Как установить Windows Updates от командной строки

Можно использовать сценарий, чтобы проверить на, загрузить и установить обновления синхронно. Я часто использую измененную версию этого vbscript для ручного исправления серверов Windows Core.

Set updateSession = CreateObject("Microsoft.Update.Session")
updateSession.ClientApplicationID = "MSDN Sample Script"

Set updateSearcher = updateSession.CreateUpdateSearcher()

WScript.Echo "Searching for updates..." & vbCRLF

Set searchResult = _
updateSearcher.Search("IsInstalled=0 and Type='Software' and IsHidden=0")

WScript.Echo "List of applicable items on the machine:"

For I = 0 To searchResult.Updates.Count-1
    Set update = searchResult.Updates.Item(I)
    WScript.Echo I + 1 & "> " & update.Title
Next

If searchResult.Updates.Count = 0 Then
    WScript.Echo "There are no applicable updates."
    WScript.Quit
End If

WScript.Echo vbCRLF & "Creating collection of updates to download:"

Set updatesToDownload = CreateObject("Microsoft.Update.UpdateColl")

For I = 0 to searchResult.Updates.Count-1
    Set update = searchResult.Updates.Item(I)
    addThisUpdate = false
    If update.InstallationBehavior.CanRequestUserInput = true Then
        WScript.Echo I + 1 & "> skipping: " & update.Title & _
        " because it requires user input"
    Else
        If update.EulaAccepted = false Then
            WScript.Echo I + 1 & "> note: " & update.Title & _
            " has a license agreement that must be accepted:"
            WScript.Echo update.EulaText
            WScript.Echo "Do you accept this license agreement? (Y/N)"
            strInput = WScript.StdIn.Readline
            WScript.Echo 
            If (strInput = "Y" or strInput = "y") Then
                update.AcceptEula()
                addThisUpdate = true
            Else
                WScript.Echo I + 1 & "> skipping: " & update.Title & _
                " because the license agreement was declined"
            End If
        Else
            addThisUpdate = true
        End If
    End If
    If addThisUpdate = true Then
        WScript.Echo I + 1 & "> adding: " & update.Title 
        updatesToDownload.Add(update)
    End If
Next

If updatesToDownload.Count = 0 Then
    WScript.Echo "All applicable updates were skipped."
    WScript.Quit
End If

WScript.Echo vbCRLF & "Downloading updates..."

Set downloader = updateSession.CreateUpdateDownloader() 
downloader.Updates = updatesToDownload
downloader.Download()

Set updatesToInstall = CreateObject("Microsoft.Update.UpdateColl")

rebootMayBeRequired = false

WScript.Echo vbCRLF & "Successfully downloaded updates:"

For I = 0 To searchResult.Updates.Count-1
    set update = searchResult.Updates.Item(I)
    If update.IsDownloaded = true Then
        WScript.Echo I + 1 & "> " & update.Title 
        updatesToInstall.Add(update) 
        If update.InstallationBehavior.RebootBehavior > 0 Then
            rebootMayBeRequired = true
        End If
    End If
Next

If updatesToInstall.Count = 0 Then
    WScript.Echo "No updates were successfully downloaded."
    WScript.Quit
End If

If rebootMayBeRequired = true Then
    WScript.Echo vbCRLF & "These updates may require a reboot."
End If

WScript.Echo  vbCRLF & "Would you like to install updates now? (Y/N)"
strInput = WScript.StdIn.Readline
WScript.Echo 

If (strInput = "Y" or strInput = "y") Then
    WScript.Echo "Installing updates..."
    Set installer = updateSession.CreateUpdateInstaller()
    installer.Updates = updatesToInstall
    Set installationResult = installer.Install()

    'Output results of install
    WScript.Echo "Installation Result: " & _
    installationResult.ResultCode 
    WScript.Echo "Reboot Required: " & _ 
    installationResult.RebootRequired & vbCRLF 
    WScript.Echo "Listing of updates installed " & _
    "and individual installation results:" 

    For I = 0 to updatesToInstall.Count - 1
        WScript.Echo I + 1 & "> " & _
        updatesToInstall.Item(i).Title & _
        ": " & installationResult.GetUpdateResult(i).ResultCode   
    Next
End If

Это, кажется, работает как очарование на это, но я не протестировал его в соответствии с Windows 7, конечно. Существует также ссылка на другую статью для предназначения для определенного обновления в случае необходимости.

Существует также модуль Powershell, который выставляет подобный опыт.

После беглого взгляда я также нашел это приложение сторонних производителей, которое также использует обновление API, но еще с некоторыми опциями (хотя требуя, чтобы Вы доверяли стороннему коду).

Если необходимо исправить операционные системы Windows, особенно после новых установок, бросьте серьезный взгляд на Офлайновый Updater.

Это использует сценарии для загрузки всех патчей, которые Вы предлагаете (так Win2000, Победа XP, Победа 2003, Vista, Win2008, Win2012 32 и 64 бита в соответствующих случаях), много язык, пакеты обновления, платформы.NET и патчи Office (XP, 2000, 2003, 2007).

После того как у Вас есть они все загруженные, Вы просто обновляете каждый патч во вторник и получаете только изменения. Хотя это действительно получает каталоги, и они становятся длиннее каждый день (много megs теперь на версию ОС/Office).

После того как у Вас есть файлы на Вашей локальной загруженной машине, существует сценарий для создания CD/образов DVD из них (это будет это автоматически для образов DVD на ОС теперь, если Вы хотели бы).

То, что я делаю, использовать карту памяти SD на 4 ГБ в читателе SD-карты, который соблюдает вкладку защиты от записи. Я раньше использовал карты на 2 ГБ, но я могу едва-едва соответствовать Победе, XP и большая часть Office основываются на ней теперь, таким образом, я шел дальше к картам на 4 ГБ.

Таким образом при поиске и устранении неисправностей машины, я доверяю вставке этого раньше перезаписываемого устройства в недоверяемое, возможно вирус заразил машину (так как я ничего не знаю об этом, я предполагаю, что это заражено), знание, что мое устройство защищается от записи.

Таким образом я могу исправить его актуальный как первый шаг.

Если Вы используете автозапуск или запускаете исполняемый файл на устройстве (ключевой, внешний HD, CD, DVD, везде, где Вы записали это) это запускает сценарий, который использует сервис Windows Update на локальную машину для применения всех обновлений, но вместо того, чтобы собраться через провод загрузить их это просто использует локальную копию.

Таким образом это может все еще взять 1 + часы для обновления машины WinXP к последнему SP и патчам, но по пути существует нулевой сетевой трафик, и можно сделать это с кабелем Ethernet, отключенным полностью.

Удивительно полезный инструмент!

Не должен сталкиваться с Microsoft, как AutoUpdate, которым были парни, кто был пред создание патча CD, который распределил образ CD. Этот инструмент обновляет сценарии, и необходимо пойти, получают все патчи на лицензированной рабочей станции Windows.

Я не верю так, Windows Update требует, чтобы некоторый ActiveX и другая интеграция с Internet Explorer работали правильно.

Так как Windows 7 является все еще едва предвыпускной версией, необходимо ожидать эти виды ошибок.

Могло бы быть мудрым для представления определенной ошибки, которую Вы имеете команде разработчиков, если Вы - член MSDN.

Центр обновления Windows из командной строки:

www.sysadminsoftware.com/udc.html

Инструмент (Updates Deployment Commander) может делать именно то, что вы просите. Вы также можете передать параметры, чтобы избежать определенных исправлений, нацелить определенные обновления, перезагрузить через N минут после завершения, создать отчеты в CSV и т. Д. Он также поставляется с парой утилит с графическим интерфейсом.

В настоящее время я не могу добавить комментарий к ответу от duffbeer703, поэтому здесь в качестве отдельного ответа:

Последняя "хорошая" версия ссылки на WSUSwiki, хранящаяся в архиве Интернета, это this. Варианты, приведённые в оригинальном ответе, описаны в этой FAQ-записи.