Вопросы Теги

Сценарий Windows для создания каталогов 3 000 файлов

Я надеюсь, что существует лучший ответ, чем это, но я прочитал повторенные отчеты лучшего успеха в преобразовании большого vmdks путем разламывания их на диски на 2 ГБ (с VMware Converter) до преобразования.

1
задан 8 June 2010 в 20:05
2 ответа

Записанный и протестированный. Скопируйте следующий код в *.bat файл. Вы захотите изменить каталог, где электронные письма существуют в начале кода. Переменная cBig была уже установлена на 3 000, но можно изменить это, если Вы хотели бы. Внизу, переместитесь, *.txt должен будет быть изменен для отражения расширения электронных писем, которые Вы перемещаете. После того как Вы протестировали его и рады, что можно удалить команды "пауза"... они просто помогают видеть то, что продолжается.Удачи!

echo off

REM **navigate to the directory
cd\bat_test

REM **store count of files to file count.txt (/a-d removes folders from count)
dir /b /a-d | find /v /c "::" > count.txt

REM **read count back in to variable (easiest way I knew how to do this)
set /p myvar=<count.txt

REM **set your upper limit (in your case 3000)
set cBig=3000



REM **quick display of the number of files
echo %myvar%

pause


REM **is the number of files larger than our upper limit? If so goto BIG
if '%myvar%' gtr '%cBig%' goto BIG



:SMALL
REM **do nothing
exit


:BIG
REM **create new directory with date and move all files
Set FDate=%Date:~-10,10%
Set Fdate=%FDate:/=-%
MD %FDate%
move *.txt ./%FDate%

pause
2
ответ дан 3 December 2019 в 22:32
  • 1
    Я думаю, что необходимо использовать dir/b/a-d вместо dir/b для предотвращения каталогов подсчета –  ggonsalv 9 June 2010 в 14:34
  • 2
    Спасибо, все еще необходимо испытать его, но выглядит очень хорошим –  user11956 9 June 2010 в 18:30

Непротестированный.CMD сценарий.

REM @echo off
setlocal enableextensions enabledelayedexpansion

  rem Print all filenames (excl. folders) in current directory into temporary text-file
  set TMPTXT=%TEMP%\%~n0.%RANDOM%.TMP
  dir /B /A-D  1>%TMPTXT%

  rem Count number of files (lines) in text-file
  set FILECNT=0
  for /F %%i in (%TMPTXT%) do (
    set /A FILECNT=!FILECNT!+1
  )
  echo Number of files in folder: !FILECNT!

  rem Is number of files greater than expected?
  if /I !FILECNT! GTR 2999  call :MoveFiles

  del %TMPTXT%
  goto :EOF

:MoveFiles
  rem Construct a folder-name based on date (remember date changes at midnight)
  rem Since the date value is locale specific, you might want to fiddle with string-replacing.
  set SUBFLDR=%DATE%
  mkdir "%SUBFLDR%"
  if /I !ERRORLEVEL! NEQ 0 (
    echo Failed to create sub-folder '%SUBFLDR%'.
    goto :EOF
  )

  rem Move only those files found in text-file to the new folder.
  for /F %%f in (%TMPTXT%) do (
    move  "%%f"  "%SUBFLDR%\."
    if /I !ERRORLEVEL! NEQ 0  echo Failed to move file '%%f'
  )
  goto :EOF
0
ответ дан 3 December 2019 в 22:32

Теги

Похожие вопросы