Как установить FTP-сервер на Linux

Вот более разумная опция, чем мои последние два предложения.

Это - сценарий, мы раньше перемещали пользователей с сервера печати на сервер печати. Это также сохранит их выбор Принтера По умолчанию.

Если бы худшее произошло, то Вы могли бы назвать этот сценарий из существующего сценария входа в систему и просто попросить, чтобы Ваши пользователи перезагрузили свои машины/выходить и заходить.

У Вас должны были бы, конечно, быть резервный сервер печати и выполнение сначала, и необходимо будет удостовериться, что все очереди печати готовы на новом сервере с теми же именами очереди печати.

Вот:

Option Explicit
'On Error Resume Next'

MigratePrint "\\svr-print-01.yourdomain.loc", "\\svr-print-02.yourdomain.loc"

Function MigratePrint(strOldServer, strNewServer)
    Dim strComputer
    Dim strShareName
    Dim objWMIService
    Dim objPrinter
    Dim objItem
    Dim colItems
    Dim WshNetwork
    Dim objshell

    strComputer = "."

    Set WshNetwork = WScript.CreateObject("WScript.Network")
    Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
    Set colItems = objWMIService.ExecQuery("Select * from Win32_Printer",,48)

    For Each objItem in colItems
        If objItem.ServerName = strOldServer Then   
            If objItem.Default = "True" Then
                strShareName = objItem.ShareName
            End If
            WshNetwork.RemovePrinterConnection objItem.ServerName & "\" & objItem.ShareName, True, True
            WshNetwork.AddWindowsPrinterConnection strNewServer & "\" &  objItem.Sharename
        End If
    Next

    Set objPrinter = CreateObject("WScript.Network") 
    objPrinter.SetDefaultPrinter (strNewServer & "\" & strShareName)
End Function