Пакетный файл для удаления всех версий Java Sun?

Существует некоторый код vbscript здесь, что необходимо смочь развернуться через Групповую политику без msi.

Выборка от: http://www.java.com/en/download/faq/remove_olderversions.xml

Со временем Вы, возможно, установили несколько версий Java для выполнения доступного содержания Java. В прошлом каждое обновление Java было установлено в отдельных каталогах в Вашей системе. Однако обновления Java теперь установлены в единственном каталоге.

Я должен удалить более старые версии Java? Мы настоятельно рекомендуем, чтобы пользователи удалили все более старые версии Java от Вашей системы. Хранение старых и неподдерживаемых версий Java в Вашей системе представляет серьезную угрозу безопасности. Удаление более старых версий Java от Вашей системы гарантирует, что JAVA-приложения будут работать с самой актуальной безопасностью и повышениями производительности в Вашей системе.

Я нашел следующий VBScript, который, в теории, правильно удаляет предыдущие версии Java. Лучше всего для чтения с самого начала, так как другие настроили его к совершенству:

http://www.appdeploy.com/messageboards/tm.asp?m=29809

Эта строка удалит все версии JAVA:

продукт wmic, где «имя вроде 'Java %% %%'» вызывает uninstall / nointeractive

Проверьте эту простую, но очень полезную команду:

wmic product where "name like 'Java(TM) 6%%'" call uninstall /nointeractive

украдено из здесь

Подтвержденный ответ, получивший наибольшее количество голосов, имеет некоторые проблемы. На основании моего тестирования идентификаторы CLSID серии 6.0 неверны.

Вот идентификаторы CLSID, которые, как я обнаружил, работают для каждой серии JRE. Замените xx на те версии, которые вы хотите удалить. Пожалуйста, используйте с https://serverfault.com/a/187552/172014

4.2_xx
{7148F0A8-6813-11D6-A77B-00B0D0142xx0}

5.0_xx
{3248F0A8-6813-11D6-A77B-00B0D0150xx0}

6.0_xx
{26A24AE4-039D-4CA4-87B4-2F832160xxF0}

7.0_xx
{26A24AE4-039D-4CA4-87B4-2F832170xxF0}

Я также рекомендую добавить / norestart после / q на тот случай, если MSI-файлы JRE серии 1.4.2 потребуют перезагрузки.

msiexec /x <insert_CLSID_here> /q /norestart

Вы все еще можете сделать это с помощью пакетного скрипта. Я использую следующий скрипт;

@ECHO OFF
REM #######################################################
REM AUTHOR: HeyVooN
REM BLOG: http://blog.teksoporte.es
REM DATE CREATED: 09/04/2015
REM Deploy Java to your Enterprise
REM This script is optimised for 32 and 64 Bit versions of Java to be installed on either 32 or 64 bit
REM operating systems. It can easily accommodate 64 bit versions of Java.
REM This script removes all previous versions of Java installed prior to (re)install any version.
REM #######################################################

REM #######################################################
REM SECTION 1 - CLEAN UP PC BEFORE INSTALLING JAVA (This section is not mandatory)
REM #######################################################
ECHO -------------------------------------------------------
ECHO STOP PROCESSES
ECHO -------------------------------------------------------
REM Assuming that processes using Java are stopped before uninstalling existing versions of Java
REM Common processes using Java: firefox.exe, iexplore.exe, chrome.exe, jusched.exe, jucheck.exe, java.exe, javacpl.exe

sc config "UI0Detect" start= disabled
sc stop UI0Detect
taskkill /F /IM jusched.exe /T
taskkill /F /IM jucheck.exe /T
taskkill /F /IM java.exe /T

ECHO -------------------------------------------------------
ECHO UNISTALL ANY PREVIOUS VERSIONS OF JAVA 32 Bit
ECHO -------------------------------------------------------
SET jver="Java 7"
SET regVar32=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall
SET myCMD=REG QUERY %regVar32% /s /f %jver%
FOR /f " usebackq delims={} tokens=2" %%i IN (`%myCMD%`) DO (
 ECHO Uninstall Key: {%%i}
 ECHO Condition: %uinstallState%
 START /WAIT MSIEXEC /x {%%i} /qn /norestart
  )

ECHO -------------------------------------------------------
ECHO UNISTALL ANY PREVIOUS VERSIONS OF JAVA 64 Bit
ECHO -------------------------------------------------------
SET jver="Java 7"
SET regVar64=HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\
SET myCMD=REG QUERY %regVar64% /s /f %jver%
FOR /f " usebackq delims={} tokens=2" %%i IN (`%myCMD%`) DO (
 ECHO Uninstall Key: {%%i}
 ECHO Condition: %uinstallState%
 START /WAIT MSIEXEC /x {%%i} /qn /norestart
  )

ECHO -------------------------------------------------------
ECHO CLEANING REGISTRY
ECHO -------------------------------------------------------
REM Removing known problem registry keys. I use the below line to SET the variable of which reg.exe to use depending on OS architecture.
REM Additional registry removal strings can be added here.
@If Defined ProgramFiles(x86) (SET "Reg32Path=%SystemRoot%\SysWOW64\reg.exe") Else (SET "Reg32Path=%SystemRoot%\System32\reg.exe")
REM %Reg32Path% DELETE HKLM\SOFTWARE\JavaSoft /va /f
%Reg32Path% DELETE "HKLM\SOFTWARE\JavaSoft\Auto Update" /va /f
%Reg32Path% DELETE "HKLM\SOFTWARE\JavaSoft\Java Update" /va /f

ECHO -------------------------------------------------------
ECHO DELETE START MENU ITEMS
ECHO -------------------------------------------------------
RD /s /q "%ProgramData%\Microsoft\Windows\Start Menu\Programs\Java"
PAUSE
EXIT /B 0

Вы можете адаптировать/изменить способ, который вам нужен. ;-)

Это сработало на меня. Он удаляет все версии Java (32-битные и 64-битные) до последней версии (на момент написания статьи это v8.0.66).

wmic product where "name like 'Java%%' and version < '8.0.66'" call uninstall