Забавный, я использовал все 3 из ответов до сих пор ;)
Вот другая опция: используйте applescript. Можно создать applescripts, которые открывают окно в текущем каталоге средства поиска, например.
У меня есть набор applescripts как этот, и я связал их с горячими клавишами с Quicksilver (или дворецкий)
по умолчанию я использую горячие клавиши, который открывает терминал в текущем каталоге средства поиска, но только если средство поиска является frontmost приложением. Иначе я просто получаю новое окно. Затем у меня также есть сценарии, которые открывают ssh сессии для определенных серверов и снова соединяются с экранной сессией. С-x опцией экранировать, у Вас может быть несколько erminal окон, смотрящих на тот же сервер, терминальный, большой :)
Править:
Это - сценарий, который я записал, который открывает новое окно, входя в текущий каталог Finder, если Средство поиска является в настоящее время активным приложением:
on run
-- Figure out if we want to do the cd (doIt)
-- Figure out what the path is and quote it (myPath)
try
tell application "Finder" to set doIt to frontmost
set myPath to finder_path()
if myPath is equal to "" then
set doIt to false
else
set myPath to quote_for_bash(myPath)
end if
on error
set doIt to false
end try
-- Figure out if we need to open a window
-- If Terminal was not running, one will be opened automatically
tell application "System Events" to set isRunning to (exists process "Terminal")
tell application "Terminal"
-- Open a new window
if isRunning then do script ""
activate
-- cd to the path
if doIt then
-- We need to delay, terminal ignores the second do script otherwise
delay 0.3
do script "cd " & myPath in front window
end if
end tell
end run
on finder_path()
try
tell application "Finder" to set the source_folder to (folder of the front window) as alias
set thePath to (POSIX path of the source_folder as string)
on error -- no open folder windows
set thePath to ""
end try
return thePath
end finder_path
-- This simply quotes all occurrences of ' and puts the whole thing between 's
on quote_for_bash(theString)
set oldDelims to AppleScript's text item delimiters
set AppleScript's text item delimiters to "'"
set the parsedList to every text item of theString
set AppleScript's text item delimiters to "'\\''"
set theString to the parsedList as string
set AppleScript's text item delimiters to oldDelims
return "'" & theString & "'"
end quote_for_bash
Для использования его откройте Script Editor и вставьте его в. Затем сохраните его где-нибудь удобный (я использую ~/Library/Scripts), и скажите QuickSilver, Butler или Google Quick Search Bar выполнять его. С QS и Butler можно установить глобальные сочетания клавиш также.
Надеюсь, это поможет,
Wout.
Я не полагаю, что IIS 6 позволяет такой уровень управления без пользовательского какого-то фильтра ISAPI. Как AuthentiX, например.