Вопросы Теги

Как перечислить Exchange, 2003 считает с любым вариантом доставки

Вы уверены, что хотите сделать это?

Outlook является совершенно счастливым наличием основного открытого mailbox/OST/PST и наличием дополнительных файлов PST, открытых одновременно. Используйте Регистрировать/открываться/Outlook Файл данных; и второе PST обнаружится как другое ответвление в Панели навигации.

Лучшая альтернатива могла бы быть должна иметь каждого пользователя, открывают старые/вторичные файлы PST в Outlook и вручную объединяются в их удобстве. Если Вы хотите, даете им период времени (скажите 90 дней), прежде чем файлы PST удалены и заархивированы.

0
задан 10 December 2010 в 13:25
1 ответ

Необходимо будет указать немного более конкретно, какие варианты доставки Вы хотите, поскольку существуют несколько. Я дам Вам этот VBScript, хотя, который даст Вам каждого пользователя в Вашем Active Directory, которому установили передающий почтовый ящик.

Я протестировал это в VM, и он работает довольно быстро, но обычные правила применяются. Протестируйте в лабораторной среде прежде, чем работать в производстве, и я не беру на себя ответственности за мир, выходящий из строя под его собственным весом, когда Вы запускаете этот скрипт.

Вызовите на командную строку с cscript /nologo altRecipient.vbs

'************************************************************************************
'* Script to find all users who have alternative recipients set
'*
'* This script was hacked together with information from the following sources.
'* I make no claim of ownership to any part of this script
'*
'*  - http://support.microsoft.com/kb/817433
'*  - http://blogs.technet.com/b/heyscriptingguy/archive/2006/03/22/how-can-i-get-a-list-of-all-the-users-who-have-an-alternate-recipient.aspx
'************************************************************************************

Dim sDomain, sADsPath, sPDC

Dim oCon ,oCmd, oRst
Set oRst = CreateObject("ADODB.Recordset")
Set oCmd = CreateObject("ADODB.Command")
Set oCon = CreateObject("ADODB.Connection")

Dim oRoot, oDomain, oADInfo, oInfo
Set oADInfo = CreateObject("ADSystemInfo")
Set oInfo = CreateObject("WinNTSystemInfo")
sPDC = oInfo.PDC & "." & oADInfo.DomainDNSName

oCon.Provider = "ADSDSOObject"
oCon.Open "Active Directory Provider"

oCmd.ActiveConnection = oCon

Set oRoot = GetObject("LDAP://rootDSE")
sDomain = oRoot.Get("defaultNamingContext")
Set oDomain = GetObject("LDAP://" & sDomain)
sADsPath = "<" & oDomain.ADsPath & ">"

oCmd.CommandText = "SELECT altRecipient, Name FROM 'LDAP://" & sPDC & "/" & sDomain & "' WHERE objectCategory='user' and altRecipient = '*'"
Set oRst = oCmd.Execute

If oRst.RecordCount = 0 Then
    WScript.Echo "no accounts found"
    WScript.Quit
End If

Do While Not oRst.EOF
    WScript.Echo  "User " & oRst.Fields("Name") & " is forwarded to " & oRst.Fields("altRecipient")
    WScript.Echo  "=========================================="
    oRst.MoveNext
Loop
1
ответ дан 4 December 2019 в 22:40

Теги

Похожие вопросы